Fundamental domains for congruence subgroups of number-field units
DefinitionTauCeti_NumberTheory_NumberField_Global_Counting_RayFundamentalDomain_Basicnumber-theorytauceti-chebotarev
For a modulus , the positivity region imposes positive coordinates at its prescribed real places. The ray fundamental domain is assembled from unit translates of the ordinary fundamental cone, indexed using the subgroup generated by congruence units and roots of unity. It provides representatives for the congruence-unit action in that region.
Formalization Note. These foundational declarations are transplanted from the Tau Ceti contributors' original source (Apache-2.0, commit 948fe4751b1fe528b6d580c522ca5d743d47f185), with compatibility adaptations for Lean 4.33.1. Mathematical proofs requiring separate theorem nodes are published separately.
Definition code
/- Transplanted from https://github.com/TauCetiProject/TauCeti at 948fe4751b1fe528b6d580c522ca5d743d47f185.
Original source copyright/license notices are retained below.
Generated exclusively from compiler declaration, command, and reference facts. -/
import Definitions.Def_TauCeti_Algebra_Order_Ring_Units
import Definitions.Def_TauCeti_GroupTheory_Index_Basic
import Definitions.Def_TauCeti_NumberTheory_NumberField_CanonicalEmbedding_UnitAction
import Definitions.Def_TauCeti_NumberTheory_NumberField_Global_RayClass_Finite
import Definitions.Def_TauCeti_NumberTheory_NumberField_Global_RayClass_Modulus
import Definitions.Def_TauCeti_NumberTheory_NumberField_Global_RayClass_Residue
import Definitions.Def_TauCeti_NumberTheory_NumberField_TotallyPositive
import Definitions.Def_TauCeti_RingTheory_DedekindDomain_Factorization
import Definitions.Def_TauCeti_RingTheory_DedekindDomain_Ideal
import Mathlib.Algebra.Group.Pi.Units
import Mathlib.Algebra.Group.Subgroup.Ker
import Mathlib.Algebra.Module.Submodule.Lattice
import Mathlib.Algebra.Order.Ring.Units
import Mathlib.Algebra.Ring.Int.Units
import Mathlib.Data.Nat.Prime.Basic
import Mathlib.Data.Nat.Prime.Defs
import Mathlib.GroupTheory.Index
import Mathlib.GroupTheory.IndexNormal
import Mathlib.GroupTheory.Solvable
import Mathlib.GroupTheory.Subgroup.Center
import Mathlib.LinearAlgebra.FreeModule.IdealQuotient
import Mathlib.NumberTheory.NumberField.Basic
import Mathlib.NumberTheory.NumberField.CanonicalEmbedding.Basic
import Mathlib.NumberTheory.NumberField.CanonicalEmbedding.FundamentalCone
import Mathlib.NumberTheory.NumberField.ClassNumber
import Mathlib.NumberTheory.NumberField.InfinitePlace.Basic
import Mathlib.NumberTheory.NumberField.InfinitePlace.TotallyRealComplex
import Mathlib.RingTheory.ClassGroup.Basic
import Mathlib.RingTheory.DedekindDomain.AdicValuation
import Mathlib.RingTheory.DedekindDomain.Factorization
import Mathlib.RingTheory.DedekindDomain.Ideal.Lemmas
import Mathlib.RingTheory.Ideal.Quotient.Defs
import Mathlib.RingTheory.Valuation.Discrete.IsDiscreteValuationRing
import Mathlib.Tactic.Group
section
set_option autoImplicit true
/-
Copyright (c) 2026 The Tau Ceti contributors. All rights reserved.
Released under Apache 2.0 license as described in the file LICENSE.
Authors: The Tau Ceti contributors
-/
/-!
# Fundamental domains for congruence subgroups of number-field units
A unit congruent to one modulo a modulus `𝔪` is constrained in two ways: it lies in a finite-index
subgroup of `(𝓞 K)ˣ`, and it is positive at every real place selected by the infinite part of `𝔪`.
The set `rayFundamentalDomain 𝔪` built here is cut out by the matching two conditions on the mixed
space: the sign conditions prescribed by `𝔪`, recorded by `posRegion 𝔪`, together with membership
in one of finitely many translates of Mathlib's `NumberField.mixedEmbedding.fundamentalCone`.
The translates are indexed by the cosets of `unitsCongruenceSubgroupSupTorsion 𝔪`, the congruence
units *joined with the roots of unity*, and not by the cosets of the congruence units alone.
Mathlib's cone is stable under the torsion, so translating it by two units differing by a root of
unity gives the same set; only with the larger index group do the translates meet each
congruence-unit orbit the same number of times, independently of the point and of the arbitrary
choice of representatives.
Consequently the domain is fundamental *modulo torsion*, in exactly the sense in which Mathlib's
cone is fundamental for the full unit group. It is measurable and stable under positive real
scalars — negative ones may violate nonempty prescribed sign conditions — every point of
`posRegion 𝔪` of nonzero mixed norm is carried into it by a unit congruent to one modulo `𝔪`, and
a congruence unit carries a point of the domain back into the domain exactly when that unit is a
root of unity. So the domain meets each congruence-unit orbit of nonzero mixed norm inside
`posRegion 𝔪` in one point, modulo the congruence units that are roots of unity. For the trivial
modulus, whose infinite part is empty and whose congruence units are all of `(𝓞 K)ˣ`, the domain
*is* Mathlib's fundamental cone.
Boundary regularity — Lipschitz parametrizability of the frontier of the norm-one section — is
developed separately; it is what upgrades the orbit description below to a count of the algebraic
integers in a fixed ray class.
## Main definitions
* `TauCeti.GlobalNumberFields.unitsCongruenceSubgroupSupTorsion`: the join of the units congruent
to one modulo `𝔪` with the roots of unity;
* `TauCeti.GlobalNumberFields.posRegion`: the sign conditions prescribed by the infinite part;
* `TauCeti.GlobalNumberFields.rayUnitRepresentative`: a normalized representative of a coset of
that subgroup;
* `TauCeti.GlobalNumberFields.rayFundamentalDomain`: the points of `posRegion 𝔪` lying in one of
the corresponding translates of Mathlib's fundamental cone.
## Main results
* `TauCeti.GlobalNumberFields.exists_unitsCongruenceSubgroup_smul_mem_rayFundamentalDomain`:
every point of `posRegion 𝔪` of nonzero norm has a congruence-unit translate in the domain;
* `TauCeti.GlobalNumberFields.unitsCongruenceSubgroup_smul_mem_rayFundamentalDomain_iff_mem_torsion`
— that translate is unique modulo the congruence units that are roots of unity;
* `TauCeti.GlobalNumberFields.index_unitsCongruenceSubgroup_mul_card_unitsCongruenceTorsion`:
the index of the congruence units against that of their join with the roots of unity;
* `TauCeti.GlobalNumberFields.rayFundamentalDomain_one`: the trivial modulus recovers Mathlib's
fundamental cone;
* `TauCeti.GlobalNumberFields.measurableSet_rayFundamentalDomain`: the domain is measurable;
* `TauCeti.GlobalNumberFields.smul_rayFundamentalDomain_inter_normLeOne`: the dilate by `c` of
the norm-≤-one section is the norm-≤-`c ^ [K:ℚ]` section.
## References
The finite-union construction is the standard ray-class refinement of the fundamental cone; see
S. Lang, *Algebraic Number Theory*, Chapter VI, Section 2.
`smul_rayFundamentalDomain_inter_normLeOne` is adapted from
`github.com/CBirkbeck/aintlib` @ `2622c61d2502159c62865a1b59fc1de473519113` (Apache-2.0),
`projects/Chebotarev/CebotarevDensity/ForMathlib/IdealCongruenceCount.lean`, where
`cone_normLe_eq_smul_normLeOne` states it privately for the fundamental cone and the trivial
modulus under the stronger hypothesis `1 ≤ t`.
-/
section
open NumberField NumberField.mixedEmbedding
open TauCeti.NumberField.Units
open scoped Pointwise
namespace TauCeti.GlobalNumberFields
variable {K : Type*} [Field K] [NumberField K]
/-! ### The congruence units and the roots of unity -/
/-- The subgroup of `(𝓞 K)ˣ` generated by the units congruent to one modulo `𝔪` and the roots of
unity.
Mathlib's fundamental cone is a fundamental domain for the unit action only modulo torsion, so
this join, rather than `unitsCongruenceSubgroup 𝔪` itself, is the subgroup whose cosets index the
translates of the cone below. -/
def unitsCongruenceSubgroupSupTorsion (𝔪 : Modulus K) : Subgroup (𝓞 K)ˣ :=
unitsCongruenceSubgroup 𝔪 ⊔ NumberField.Units.torsion K
/-- The units congruent to one modulo `𝔪` lie in `unitsCongruenceSubgroupSupTorsion 𝔪`. -/
theorem unitsCongruenceSubgroup_le_unitsCongruenceSubgroupSupTorsion (𝔪 : Modulus K) :
unitsCongruenceSubgroup 𝔪 ≤ unitsCongruenceSubgroupSupTorsion 𝔪 :=
le_sup_left
/-- A unit lies in `unitsCongruenceSubgroupSupTorsion 𝔪` exactly when it is the product of a unit
congruent to one modulo `𝔪` and a root of unity. -/
theorem mem_unitsCongruenceSubgroupSupTorsion {𝔪 : Modulus K} {u : (𝓞 K)ˣ} :
u ∈ unitsCongruenceSubgroupSupTorsion 𝔪 ↔
∃ v ∈ unitsCongruenceSubgroup 𝔪, ∃ ζ ∈ NumberField.Units.torsion K, v * ζ = u :=
Subgroup.mem_sup
instance unitsCongruenceSubgroupSupTorsion_finiteIndex (𝔪 : Modulus K) :
(unitsCongruenceSubgroupSupTorsion 𝔪).FiniteIndex :=
Subgroup.finiteIndex_of_le (unitsCongruenceSubgroup_le_unitsCongruenceSubgroupSupTorsion 𝔪)
/-! ### The sign conditions prescribed by the infinite part -/
/-- The **positivity region** of a modulus: the points of the mixed space whose coordinate at every
real place in `𝔪.infinitePart` is positive.
These are the sign conditions defining congruence to one modulo `𝔪`: the mixed embedding of an
element congruent to one lies in this region, and the region is stable under the action of a unit
congruent to one. -/
def posRegion (𝔪 : Modulus K) : Set (mixedSpace K) :=
{x | ∀ w ∈ 𝔪.infinitePart, 0 < x.1 w}
@[simp] theorem mem_posRegion {𝔪 : Modulus K} {x : mixedSpace K} :
x ∈ posRegion 𝔪 ↔ ∀ w ∈ 𝔪.infinitePart, 0 < x.1 w := Iff.rfl
/-- The positivity region is stable under the action of a unit congruent to one modulo `𝔪`: such a
unit is positive at every real place prescribed by `𝔪`. -/
theorem unitSMul_mem_posRegion {𝔪 : Modulus K} {x : mixedSpace K} (hx : x ∈ posRegion 𝔪)
{u : (𝓞 K)ˣ} (hu : u ∈ unitsCongruenceSubgroup 𝔪) : u • x ∈ posRegion 𝔪 := by
refine fun w hw ↦ ?_
have hcoord : (u • x).1 w = InfinitePlace.embedding_of_isReal w.2 (u : K) * x.1 w := by
rw [unitSMul_smul]
simp
have hupos : 0 < InfinitePlace.embedding_of_isReal w.2 (u : K) := by
simpa using (mem_unitsCongruenceSubgroup.mp hu).pos hw
rw [hcoord]
exact mul_pos hupos (hx w hw)
/-! ### The fundamental domain -/
/-- A representative of a coset of `unitsCongruenceSubgroupSupTorsion 𝔪`.
The identity coset is normalized to have representative `1`. This normalization makes the
fundamental domain for the trivial modulus agree literally with Mathlib's fundamental cone, rather
than with an unspecified unit translate of it. -/
noncomputable def rayUnitRepresentative (𝔪 : Modulus K)
(q : (𝓞 K)ˣ ⧸ unitsCongruenceSubgroupSupTorsion 𝔪) : (𝓞 K)ˣ := by
classical
exact if q = 1 then 1 else q.out
/-- The representative of the identity coset is the identity unit. -/
@[simp]
theorem rayUnitRepresentative_one (𝔪 : Modulus K) : rayUnitRepresentative 𝔪 1 = 1 := by
simp [rayUnitRepresentative]
/-- The chosen representative maps back to the coset it represents. -/
@[simp]
theorem rayUnitRepresentative_mk (𝔪 : Modulus K)
(q : (𝓞 K)ˣ ⧸ unitsCongruenceSubgroupSupTorsion 𝔪) :
QuotientGroup.mk (rayUnitRepresentative 𝔪 q) = q := by
by_cases hq : q = 1
· subst q
simp
· simpa only [rayUnitRepresentative, hq, ↓reduceIte] using QuotientGroup.out_eq' q
/-- The **ray fundamental domain** associated to a modulus: the points of the mixed space that
carry the signs prescribed by the infinite part of `𝔪` and that one chosen unit-coset
representative moves into Mathlib's fundamental cone.
Equivalently, this is the intersection of `posRegion 𝔪` with the union of the translates
`rayUnitRepresentative 𝔪 q • fundamentalCone K` over the finite quotient of the unit group by
`unitsCongruenceSubgroupSupTorsion 𝔪`; see `rayFundamentalDomain_eq_iUnion`. -/
def rayFundamentalDomain (𝔪 : Modulus K) : Set (mixedSpace K) :=
{x | x ∈ posRegion 𝔪 ∧ ∃ q : (𝓞 K)ˣ ⧸ unitsCongruenceSubgroupSupTorsion 𝔪,
(rayUnitRepresentative 𝔪 q)⁻¹ • x ∈ fundamentalCone K}
/-- Membership in the ray fundamental domain, unfolded to the sign conditions and a chosen unit
coset. -/
theorem mem_rayFundamentalDomain_iff {𝔪 : Modulus K} {x : mixedSpace K} :
x ∈ rayFundamentalDomain 𝔪 ↔
x ∈ posRegion 𝔪 ∧ ∃ q : (𝓞 K)ˣ ⧸ unitsCongruenceSubgroupSupTorsion 𝔪,
(rayUnitRepresentative 𝔪 q)⁻¹ • x ∈ fundamentalCone K :=
Iff.rfl
/-- A point of the ray fundamental domain carries the signs prescribed by `𝔪`. -/
theorem mem_posRegion_of_mem_rayFundamentalDomain {𝔪 : Modulus K} {x : mixedSpace K}
(hx : x ∈ rayFundamentalDomain 𝔪) : x ∈ posRegion 𝔪 :=
(mem_rayFundamentalDomain_iff.mp hx).1
/-- Every point of the ray fundamental domain has positive mixed norm. -/
theorem norm_pos_of_mem_rayFundamentalDomain {𝔪 : Modulus K} {x : mixedSpace K}
(hx : x ∈ rayFundamentalDomain 𝔪) : 0 < mixedEmbedding.norm x := by
obtain ⟨q, hq⟩ := (mem_rayFundamentalDomain_iff.mp hx).2
simpa only [norm_unit_smul] using fundamentalCone.norm_pos_of_mem hq
/-- Multiplication by a root of unity congruent to one modulo `𝔪` preserves membership in the ray
fundamental domain: the cone translates are stable under the torsion, and the prescribed signs are
preserved because the unit is a congruence unit.
This is not a `simp` lemma: Mathlib's `NumberField.mixedEmbedding.unitSMul_smul` is itself `simp`
and rewrites the left-hand side to a product, so the statement is not in `simp` normal form. -/
theorem torsion_smul_mem_rayFundamentalDomain_iff {𝔪 : Modulus K} {x : mixedSpace K}
{ζ : (𝓞 K)ˣ} (hζ : ζ ∈ NumberField.Units.torsion K)
(hζ' : ζ ∈ unitsCongruenceSubgroup 𝔪) :
ζ • x ∈ rayFundamentalDomain 𝔪 ↔ x ∈ rayFundamentalDomain 𝔪 := by
have mem_of_mem {y : mixedSpace K} (hy : y ∈ rayFundamentalDomain 𝔪) {η : (𝓞 K)ˣ}
(hη : η ∈ NumberField.Units.torsion K) (hη' : η ∈ unitsCongruenceSubgroup 𝔪) :
η • y ∈ rayFundamentalDomain 𝔪 := by
obtain ⟨hpos, q, hq⟩ := mem_rayFundamentalDomain_iff.mp hy
refine mem_rayFundamentalDomain_iff.mpr ⟨unitSMul_mem_posRegion hpos hη', q, ?_⟩
rw [unitSMul_comm]
exact fundamentalCone.torsion_smul_mem_of_mem hq hη
refine ⟨fun h ↦ ?_, fun h ↦ mem_of_mem h hζ hζ'⟩
have h := mem_of_mem h ((NumberField.Units.torsion K).inv_mem hζ)
((unitsCongruenceSubgroup 𝔪).inv_mem hζ')
rwa [inv_smul_smul] at h
/-- The roots of unity congruent to one modulo `𝔪`. By
`unitsCongruenceSubgroup_smul_mem_rayFundamentalDomain_iff_mem_torsion` these are exactly the
congruence units carrying a point of the ray fundamental domain back into it. -/
def unitsCongruenceTorsion (𝔪 : Modulus K) : Subgroup (𝓞 K)ˣ :=
unitsCongruenceSubgroup 𝔪 ⊓ NumberField.Units.torsion K
/-- Membership in `unitsCongruenceTorsion`, unfolded to the two defining conditions. The
definition is not exposed, so `Subgroup.mem_inf` cannot see through it from another module. -/
@[simp]
theorem mem_unitsCongruenceTorsion {𝔪 : Modulus K} {u : (𝓞 K)ˣ} :
u ∈ unitsCongruenceTorsion 𝔪 ↔
u ∈ unitsCongruenceSubgroup 𝔪 ∧ u ∈ NumberField.Units.torsion K :=
Iff.rfl
/-- `unitsCongruenceTorsion 𝔪` is finite, being a subgroup of the roots of unity. -/
instance (𝔪 : Modulus K) : Finite (unitsCongruenceTorsion 𝔪) :=
Finite.of_injective _ (Subgroup.inclusion_injective inf_le_right)
/-- **Existence of a representative.** Every point carrying the signs prescribed by `𝔪` and of
nonzero mixed norm is moved into the ray fundamental domain by a unit congruent to one modulo
`𝔪`. -/
theorem exists_unitsCongruenceSubgroup_smul_mem_rayFundamentalDomain (𝔪 : Modulus K)
{x : mixedSpace K} (hx : mixedEmbedding.norm x ≠ 0) (hpos : x ∈ posRegion 𝔪) :
∃ u : (𝓞 K)ˣ, u ∈ unitsCongruenceSubgroup 𝔪 ∧ u • x ∈ rayFundamentalDomain 𝔪 := by
obtain ⟨u, hu⟩ := fundamentalCone.exists_unit_smul_mem hx
set q : (𝓞 K)ˣ ⧸ unitsCongruenceSubgroupSupTorsion 𝔪 := QuotientGroup.mk u⁻¹ with hq
set r : (𝓞 K)ˣ := rayUnitRepresentative 𝔪 q with hr
have hmem : r⁻¹ * u⁻¹ ∈ unitsCongruenceSubgroupSupTorsion 𝔪 :=
QuotientGroup.eq.mp (by rw [hr, rayUnitRepresentative_mk, hq])
obtain ⟨v, hv, ζ, hζ, hvζ⟩ := mem_unitsCongruenceSubgroupSupTorsion.mp hmem
have hv' : v⁻¹ ∈ unitsCongruenceSubgroup 𝔪 := (unitsCongruenceSubgroup 𝔪).inv_mem hv
refine ⟨v⁻¹, hv', mem_rayFundamentalDomain_iff.mpr
⟨unitSMul_mem_posRegion hpos hv', q, ?_⟩⟩
have hrinv : r⁻¹ = v * ζ * u := by rw [hvζ]; group
have heq : r⁻¹ • (v⁻¹ • x) = ζ • (u • x) := by
rw [← mul_smul, ← mul_smul, hrinv]
congr 1
simp [mul_comm, mul_assoc]
rw [← hr, heq]
exact fundamentalCone.torsion_smul_mem_of_mem hu hζ
end TauCeti.GlobalNumberFields
end
end
Source