LeanProofs.Foundations.BasisElements
DefinitionGrade4_LeanProofs_Foundations_BasisElementsclifford-algebraleanproofs-grade4rosetta
Foundational definitions and structural lemmas from LeanProofs.Foundations.BasisElements, required by the selected LeanProofs theorem graph.
Definition code
/-
Bivector basis elements for Cl(1,3).
The 6 basis bivectors γ_μν = γ_μ γ_ν span the bivector subspace ∧²ℝ^{3,1}.
Convention matching paper eq. (2) and Rust's StaBivector:
Electric: γ₀₁, γ₀₂, γ₀₃ (indices E₁, E₂, E₃)
Magnetic: γ₂₃, γ₃₁, γ₁₂ (indices B₁, B₂, B₃)
Paper reference: §2.1, equations (2)-(3).
Rust reference: bivector_field.rs (StaBivector components [E₁,E₂,E₃,B₁,B₂,B₃])
-/
import Definitions.Def_Grade4_LeanProofs_Foundations_STADef
namespace LeanProofsGrade4P2M
noncomputable section
/-! ## Bivector basis elements -/
/-- Bivector basis element γ_μν = γ_μ · γ_ν. -/
def gammaProd (μ ν : Fin 4) : STA := gamma μ * gamma ν
-- Electric bivectors (timelike-spacelike planes)
def γ01 : STA := gammaProd 0 1
def γ02 : STA := gammaProd 0 2
def γ03 : STA := gammaProd 0 3
-- Magnetic bivectors (spacelike-spacelike planes)
def γ23 : STA := gammaProd 2 3
def γ31 : STA := gammaProd 3 1
def γ12 : STA := gammaProd 1 2
/-! ## Antisymmetry -/
/-! ## Squares of bivector basis elements
Electric: (γ₀ᵢ)² = -(γ₀²)(γᵢ²) = -(+1)(-1) = +1
Magnetic: (γᵢⱼ)² = -(γᵢ²)(γⱼ²) = -(-1)(-1) = -1
The key step: γ_μ γ_ν γ_μ γ_ν = -(γ_μ²)(γ_ν²) for μ ≠ ν,
using γ_ν γ_μ = -γ_μ γ_ν (anticommutativity).
-/
/-- Helper: (γ_μ γ_ν)² = -(γ_μ²)(γ_ν²) for distinct μ, ν. -/
theorem gammaProd_sq {μ ν : Fin 4} (h : μ ≠ ν) :
gammaProd μ ν * gammaProd μ ν =
-(gamma μ * gamma μ) * (gamma ν * gamma ν) := by
unfold gammaProd
have hac : gamma ν * gamma μ = -(gamma μ * gamma ν) :=
gamma_anticomm_ne (Ne.symm h)
-- γ_μ γ_ν γ_μ γ_ν
-- = γ_μ (γ_ν γ_μ) γ_ν [assoc]
-- = γ_μ (-γ_μ γ_ν) γ_ν [anticomm]
-- = -(γ_μ γ_μ)(γ_ν γ_ν) [simplify]
have step1 : gamma μ * gamma ν * (gamma μ * gamma ν) =
gamma μ * (gamma ν * gamma μ) * gamma ν := by
simp only [mul_assoc]
have step2 : gamma μ * (gamma ν * gamma μ) * gamma ν =
gamma μ * (-(gamma μ * gamma ν)) * gamma ν := by
rw [hac]
have step3 : gamma μ * (-(gamma μ * gamma ν)) * gamma ν =
-(gamma μ * (gamma μ * gamma ν) * gamma ν) := by
simp only [mul_neg, neg_mul]
have step4 : gamma μ * (gamma μ * gamma ν) * gamma ν =
gamma μ * gamma μ * (gamma ν * gamma ν) := by
simp only [← mul_assoc]
rw [step1, step2, step3, step4, neg_mul]
/-- γ₀₁² = 1 (electric bivectors square to +1). -/
theorem γ01_sq : γ01 * γ01 = 1 := by
rw [γ01, gammaProd_sq (by decide : (0 : Fin 4) ≠ 1)]
rw [gamma0_sq, gamma1_sq]
simp
/-- γ₂₃² = -1. -/
theorem γ23_sq : γ23 * γ23 = -1 := by
rw [γ23, gammaProd_sq (by decide : (2 : Fin 4) ≠ 3)]
rw [gamma2_sq, gamma3_sq]
simp
end
end LeanProofsGrade4P2M
Source